File: TK.TK of Disk: Disks/MyPDP/m8-blue-rka1-rkb1
(Source file text)
/TK.TK 13-MAY-80
/THIS TASK CAN BE CALLED FROM ANY TERMINAL WITH THE ^B,T COMMAND
/IT WILL ACCEPT ONE LINE, WHICH SHOULD START WITH DIGIT,SEPARATOR.
/THE DIGIT IS THE NUMBER OF THE TERMINAL TO WHICH THE REST OF THE LINE
/IS SEND.
*200
"T^100+"K&3777 /TASK NAME IS "TALK BACK"
200 /I HOPE ONE PAGE IS SUFFICIENT
XBUF, BUF /POINTER TO LINE BUFFER
XBASE, 0
TALK, DCA XBASE /THIS TASK GETS CALLED FROM CB
TAD XBASE /GET BASE OF BG
TAD (UKB
JMS DEFER /AND NOW TCBP OF MY KB
TAD (-TCBTAB-4 /INDEX IN NAMLST
CLL RTR
RAR /TASK NUMBER
TAD (NAMLST
CDF 0
JMS DEFER /IN F 0
DCA BUF /THIS SHOULD BE THE NAME OF AN INPUT HANDLER
CDTOIF
TAD XBUF /CALL THE LINE INPUT TASK
JMS MONITOR
CALL
"I^100+"N&3777
JMP TAEXIT /SOMETHINGS WRONG, LET THEM TRY AGAIN
SZA CLA /ERRORS ?
JMP TAEXIT /YES, QUIT
TAD BUF+2 /GET THE TARGET TERMINAL NUMBER
TAD (-260
SPA SNA
JMP TAEXIT /BAD NUMBER, QUIT
TAD (-TTYMAX
SMA SZA
JMP TAEXIT /BAD NUMBER, QUIT
TAD ("K^100+"0&3777+TTYMAX /MAKE TASK NAME
DCA ZTEM1
TAD BUF
AND C7 /GET DEVICE NUMBER
TAD C260 /MAKE ASCII
DCA BUF+2 /SO THEY NOW WHERE ITS COMING FROM
TAD (":
DCA BUF+3 /PRINT :
TAD XBUF
DCA ZTEM2
TKCR, ISZ ZTEM2
TAD I ZTEM2
TAD M215 /SEARCH CR
SZA CLA
JMP TKCR
TAD (207
DCA I ZTEM2 /INSERT BEEP
ISZ ZTEM2
TAD C215
DCA I ZTEM2 /CR AGAIN
TAD ZTEM1
DCA BUF
TAD XBUF
JMS MONITOR
CALL
"I^100+"N&3777
JMP TAEXIT /THAT'S A PITY, CAN'T GET HIM
TAEXIT, JMS MONITOR
EXIT SWPOUT
BUF, 0 /GETS DEVICE HANDLER NAME
-70 /MINUS BUFFER LENGTH
BST=.
IFNDEF GERMAN <
"D;"e;"s;"t;"#;",;"T;"e;"x;"t;":;240 >
IFDEF GERMAN <
"Z;"i;"e;"l;"#;",;"T;"e;"x;"t;":;240 >
ZBLOCK 70-.+BST
PAGE
$-$-$