File: LPTSPL.PA of Tape: OS8/OS8-Latest/new-5

(Source file text) 

---

/LPTSPL PROG FOR LOG $MSG

/	WVDM 15-0CT-80

	MSG=6013
	BKILL=7460
	DOLFLG=7776
	BIPCCL=7777

/	PAL LPTSPL
/	LO LPTSPL
/	SA SYS LPTSPL=6403

/	ONLY!! FOR BATCH V40B!!
/
/	CALLED BY CCL-COMMAND 'PRQ' = PRESET QUESTION
	FIELD 0
	*2000
PRSTRT,	CLA
	CLA
	CDF 0
	TAD I	(BIPCCL
	RAL
	SMA CLA		/IS BATCH ACTIVE ?
	JMP I	(7605	/NO, FORGET IT
	TAD I	(BIPCCL
	AND	(70	/GET BATCH FIELD
	TAD	(CDF 0
	DCA	BATCDF+1	/SET FOR BAT FIELD ACCES
	JMS	BATCDF
	TAD	(CIF CDF
	DCA I	(MSG+11
	TAD	(MSG+13&177+5600	/'JMP I MSG+13'
	DCA I	(MSG+12
	TAD	(PRENTR	/REENTRY ADDRESS
	DCA I	(MSG+13
	CDF 0
	JMP I	(7605	/THAT'S IT.. WE COME BACK
/--------------------------------------------------------
PRENTR,	JMS	BATCDF
	TAD	(1373	/'TAD (207'
	DCA I	(MSG+11
	TAD	(4772	/'JMS I (TTYOUT'
	DCA I	(MSG+12
	TAD	(4771	/'JMS I (TTY'
	DCA I	(MSG+13	/'MSG' TRAP IS CLEAN AGAIN
	CDF 0
	KCC
	TAD	(PROMPT
	JMS	PRPR	/PRINT (J,N):
	KSF
	JMP	.-1
	KRB		/GET USER TYPE-IN
	AND	(177
	TAD	(200
	TAD	(-"N	/DID HE TYPE "N EIN" ?
	SZA
	TAD	("N-"n	/or "n ein" ?
	SNA CLA
	CLA STL RAR	/YES, SET AC=4000
	JMS	BATCDF
	DCA I	(DOLFLG	/SET BATCH EROR STATUS
	TAD I	(DOLFLG
	CDF 0
	SNA CLA
	TAD	(JAMES-NORA
	TAD	(NORA
	JMS	PRPR	/PRINT Ja OR Nein
PREX,	CLA STL RTL
	TAD	BATCDF+1
	DCA	.+1
	HLT
	JMP I	(MSG+14
PRPR,	0
	DCA	PRPNT
	TAD I	PRPNT
	TLS
	TSF
	JMP	.-1
	ISZ	PRPNT
	SZA CLA
	JMP	PRPR+2
	JMP I	PRPR

BATCDF,	0
	HLT
	JMP I	BATCDF

PRCHAR,	0
PRPNT,	0
	PAGE
PROMPT,	207
	"A
	"n
	"t
	"w
	"o
	"r
	"t
	" 
	"(
	"J
	",
	"N
	")
	" 
	":
	" 
	000
JAMES,	210
	"J
	"a
	215
	212
	000
NORA,	210
	"N
	"e
	"i
	"n
	215
	212
	000

	PAGE
	FIELD 0
	*PRSTRT
	$-$-$

---