File: CCLDAT.MA of Tape: OS8/OS8-V40/v40-6

(Source file text) 

---

/CCL DATE+TIME FOR KBM V40
/
/
/
/
/
/
/COPYRIGHT  (C)  1979 BY DIGITAL EQUIPMENT CORPORATION
/		 AND 1979 BY DATAPLAN GMBH
/
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/

/3	CCL DATE COMMAND
/	VERSION=4A

	.ENTRY DATE
	.EXTERNAL WEEKLST,MONLST
	.EXTERNAL OTOD,PRWD,LISPRT
	.EXTERNAL CRLF,LOOK,CHAIN
	.EXTERNAL YDATE,ERROR

	.NOLIST
	.INCLUDE OUT:CCLDEF.MA
	.LIST

	.RSECT CCLDAT
	FIELD 1

	OVLSTR==.	/START OF OVERLAYS
			/*** DATE MUST BE LEVEL 1 OVERLAY 0 ***
			/AND FIRST SUBROUTINE IN THAT LEVEL
DATE,	0
	SM8		/SKIP ON MULTI8
	SKP CLA
	JMS I	(TIME
	TAD I (MDATE
	SNA
	JMP NODATE
	DCA DATEM
	TAD DATEM
	BSW
	CLL RTR
	AND (17
	DCA	TM1
	TAD DATEM
	AND (7
	DCA TM2
	CDF 0
	TAD I (BATCCL
	CDF 10
	CLL RTR
	RTR
	AND (30
	TAD TM2
	DCA TM2
	TAD TM2
	TAD (70.
	JMS I (OTOD
	DCA YEAR
	TAD DATEM
	CLL RTR
	RAR
	AND (37
	DCA DATEM
	TAD DATEM
	JMS I (OTOD
	DCA DAY
	STL CLA RTL	/2
	TAD TM2
	CLL RTR
	SNL SMA
	JMP 1$
	ISZ	JAN
	ISZ	FEB
1$:	AND (37
	TAD TM2
	TAD (3
	TAD DATEM
	DCA DATEM
	TAD TM1
	TAD (JAN-1
	DCA TM2
	TAD I TM2
	TAD DATEM
2$:	CLL
	TAD (-7
	SZL
	JMP 2$
	TAD (7
	JMS I	(LISPRT
	WEEKLST
	TAD	(', 
	JMS I	(PRWD
.IF DF GERMAN <
	TAD	DAY
	JMS I	(PRWD
	TAD	('. 
	JMS I	(PRWD>
	TAD	TM1
	JMS I	(LISPRT
	MONLST
.IF NDF GERMAN <
	TAD	(' @
	JMS I (PRWD	/SPACE
	TAD DAY
	JMS I (PRWD>
	TAD	(', 
	JMS I	(PRWD
	TAD	('19	/PRINT ", 19"
	JMS I	(PRWD
	TAD YEAR
	JMS I (PRWD
	JMS I (CRLF
	JMS I (LOOK	/LOOKUP SYS:DATE.SV
	YDATE
	JMP I DATE	/DO NOTHING IF IT'S NOT THERE
	JMP I (CHAIN	/CHAIN TO IT, IF IT'S THERE
NODATE,	JMS I (ERROR
	20.
TM1,	0
TM2,	0
DATEM,	0
DAY,	0
YEAR,	0
JAN,	0
FEB,	3
	4;0;2;5;0;3;6;1;4;6

	PAGE
TIME,	0
	CLA
	GIOT		/GET TIME OF DAY
	DCA	T$
	TAD	T$
	BSW
	AND	(77
	JMS I	(OTOD
	JMS I	(PRWD
	TAD	(':@
	JMS I	(PRWD
	TAD	T$
	AND	(77
	JMS I	(OTOD
	JMS I	(PRWD
	TAD	('  
	JMS I	(PRWD
	JMP I	TIME
T$:	0
	PAGE

---