File: CCLSB2.MA of Tape: OS8/OS8-V40/v40-6

(Source file text) 

---

/CCL SUBROUTINES 2 FOR KBM V40
/
/
/
/
/
/
/
/
/COPYRIGHT  (C)  1979 BY DIGITAL EQUIPMENT CORPORATION
/		 AND 1979 BY DATAPLAN GMBH
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/

/2	CCL SUBROUTINES PART 2
/	VERSION=4A

	GERMAN=1

	.ENTRY TRMSUB,REQSUB,CANSUB
	.EXTERNAL LOOK,CHAIN,YTERMIN,PRINT,LEAVE

	.NOLIST
	.INCLUDE OUT:CCLDEF.MA
	.LIST

	.RSECT CCLSB2
	FIELD 1
	.SBTTL TERMINATE COMMAND

TRMSUB,	0
	CDF 0
	TAD I (OS78BIT
	CDF 10
	AND (200
	SNA CLA
	JMP I TRMSUB	/BACKSPACE, NOT TERMINATE
	JMS I (LOOK	/LOOKUP TERMIN.SV
	YTERMIN
	SKP CLA
	JMP I (CHAIN
/	6073
/	6002
	JMS I (PRINT
	BADEV
	JMP I (LEAVE
CANSUB,	0
	TAD I (SCOPE
	AND (4
	SNA CLA
	JMP FOO4
	TAD I (SCOPE
	AND (7773
	DCA I (SCOPE	/TURN OFF SYMBIONT BIT
	CDF 0
	TAD I (BATCCL
	RTL
	SZL CLA
	JMP 3$
	TAD I (BATCCL
	AND (7707
	DCA I (BATCCL
3$:	CDF 10
	JMS I (PRINT
	OFFMSG
	JMS I (PRINT
	ME2MSG
	CIF CDF 30
	JMP I (3	/GO TO MAGIC SPOT IN SYMBIONT LAND

FOO3,	JMS I (PRINT
	ALRACT
	JMP I (LEAVE
FOO4,	JMS I (PRINT
	NOTACT
	JMP I (LEAVE
	PAGE
	.SBTTL REQUEST COMMAND

REQSUB,	0
	TAD I (MIFILE
	AND (17
	TAD (DVHNDL-1
	DCA REQT
	TAD I REQT
	TAD (-SHNDLR
	SZA CLA
	JMP FOO		/*** FILE NOT ON SYS:
	TAD I (MIFILE+1
	DCA BLK
	CDF 0
	TAD I (BATCCL
	AND (70
	TAD (-20
	SNA CLA
	JMP 1$
	RTL
	SZL CLA
	JMP FOO2
	TAD I (BATCCL
	AND (7707
	TAD (20
	DCA I (BATCCL
1$:	CDF 10
	TAD I (SCOPE
	AND (4
	SZA CLA
	JMP FOO3
	TAD I (SCOPE
	AND (7773
	TAD (4
	DCA I (SCOPE
	JMS I (PRINT
	ONMSG
	JMS I (PRINT
	MEMMSG
	JMS I (USR	/CHAIN TO IT
	6
BLK,	0

REQT,	0
FOO,	JMS I (PRINT
	SYSMSG
	JMP I (LEAVE

FOO2,	JMS I (PRINT
	BATMSG
	JMP I (LEAVE
	PAGE
	.ENABLE ASCII
.IF NDF GERMAN <
SYSMSG,	TEXT	"#Symbiont must be on SYS:"
BATMSG,	TEXT	"#Cannot start symbiont from BATCH"
ONMSG,	TEXT	"[Starting symbiont]"
BADEV,	TEXT	"#Illegal OS/8 command"
OFFMSG,	TEXT	"[Shutting down symbiont]"
NOTACT,	TEXT	"%No symbiont is active"
ALRACT,	TEXT	"#Request denied - symbiont already running"
MEMMSG,	TEXT	"[12K Memory]"
ME2MSG,	TEXT	"[16K Memory]
	>
.IF DF GERMAN <
SYSMSG,	TEXT	"#Symbiont muss auf SYS: sein"
BATMSG,	TEXT	"#Symbiont-Start nicht unter BATCH"
ONMSG,	TEXT	"[Symbiont-Start]"
BADEV,	TEXT	"#Falsches Kommando"
OFFMSG,	TEXT	"[Symbiont endet]"
NOTACT,	TEXT	"%Es laeuft kein Symbiont"
ALRACT,	TEXT	"#Nein! - Symbiont laeuft schon"
MEMMSG,	TEXT	"[12K Speicher]"
ME2MSG,	TEXT	"[16K Speicher]
	>
	.ENABLE SIXBIT

---