<div id='wikitext'>
<pre><b> File: PDPPLW.RA of Tape: Sources/Fortran/s2</b></pre>
<pre><b>(Source file text) </b></pre>
<hr />
<pre>
	FIELD1	PDPPLT
	EXTERN ONQI
	EXTERN	#DISMS
INTST,	0
	CLA CMA
	DCA%	PBFCNT+1
	TAD	PUBFMX+1
	CIA
	TAD	PUBFMN+1
	DCA%	PMBFLG+1
	TAD 	PUBFMN+1
	DCA%	OCHAR+1
	TAD	PUBFMN+1
	DCA%	ICHAR+1
	TAD	DISMS+1
	DCA%	PDISMS+1
	DCA%	DXHOLD+1
	DCA%	DYHOLD+1
	6077		/CLEAR ALL
	6075			/PLOT
	6061			/LOAD X,CL. AC
	6073			/LOAD Y,CL. AC,INT
	6051			/SKIP P.P.
	JMP	.-1
	6077			/CLEAR ALL
	6056			/FAST PLOT
	TAD	A14		/ENABLE FORTRAN FLAG,INH. INTSFY
	6050
	CLA
	CDF	10
	JMS%	QPLDBL+1
	JMS%	VONQI+1
	6053			/SKP F.P 
	ADDR	INTPLT
	CIF CDF
	JMP%	INTST
VONQI,	ADDR	ONQI

SETUP,	0
	TAD	SETXR
	AND 	A3
	CLL RAR
	SZA
	SNL CLA
	IAC
	CLL
	JMS%	QPLDBL+1
	CIF CDF
	JMP%	SETUP
QPLDBL,	ADDR	PLDBL
A3,	3
A14,	14			/ENABLE PPEI,INH. PEN INTENS.
SETXR,
OCHAR,	ADDR	POCHAR+1
PBFCNT,	ADDR	BUFCNT
ICHAR,	ADDR	PICHAR+1
PMBFLG,	ADDR	MBUFLG
PUBFMN,	ADDR	USBFMN
PUBFMX,	ADDR	USBFMX
DISMS,	ADDR	#DISMS
PDISMS,	ADDR	DISPTR
DXHOLD,	ADDR	XHOLD
DYHOLD,	ADDR	YHOLD
USBFMN,	ZBLOCK 70
USBFMX,	0

	ORG	INTST+200

LEFT,	0
	JMS	GETXYS
	RTR
	RTR
	RTR
	JMS	PASSXY
	CIF CDF
	JMP%	LEFT
P7,	7
PASSXY,	0
	DCA	LETCD2
	TAD	LETCD2
	CLL RTR
	RAR
	AND	P7
	DCA	LETCD1
	TAD	LETCD2
	AND	P7
	DCA	LETCD2
	JMP%	PASSXY
RIGHT,	0
	JMS	GETXYS
	JMS	PASSXY
	CIF CDF
	JMP%	RIGHT
LETCOD,	0
LETCD1,	0
LETCD2,	0

GETXYS,	0
	TAD	LETCOD
	CLL
	TAD	LOCNPT
	DCA	LETCD2
	RAL
	TAD	LOCNFL
	CLL RTL
	RAL
	TAD	CDFINS
	DCA	NFLD
NFLD,	0
	TAD%	LETCD2
	CDF 10
	JMP%	GETXYS
CDFINS,	6201
LOCNFL,	0
LOCNPT,	0

OCT8BL,	6064
	6065
	100
	101
	1
	101
	200
	201
	1
	201
	100
	102
	2
	102
	200
	202
	2
	202

FIGURE,	0
	CLL
	TAD	RATIO2
	TAD	HOLD2
	DCA	HOLD2
	RAL
	TAD	RATIO1
	TAD	HOLD1
	DCA	HOLD1
	CLL
	TAD	HOLD1
	RAL
	SNL
	JMP	MAJONL
	CLL RAR
	DCA	HOLD1
	IAC
	JMP%	FIGURE
MAJONL,	CLA
	JMP%	FIGURE
RATIO,	0
RATIO1,	0
RATIO2,	0
HOLD1,	0
HOLD2,	0

SPCAS,	0
	DCA	HOLD1
	TAD	RFUDGE
	DCA	HOLD2
	JMP%	SPCAS
RFUDGE,	1000
	ORG	LEFT+200
NXTLCN,
PLETPS,	ADDR	LOCNPT
ATSW,
PLCNM1,	ADDR	LOCNFL
TXTADR,	0
	0
	0
LETTER,	0
PSYMB,	ADDR	SYMTBL
PP7,	7

FINDLF,	0
	TAD	TXTADR+1
	AND	PP7
	CLL RTL
	RAL
	TAD	CDF
	DCA	DOCDF
DOCDF,	NOP
	TAD%	TXTADR+2
	CDF 10
	DCA	LETTER
	TAD	LETTER
	7002	/BSW
	AND	P77
	JMS	FINDIT
	ISZ	TXTADR+2
	JMP	FLDOK
	ISZ	TXTADR+1
FLDOK,	CIF CDF
	JMP%	FINDLF

FINDIT,	0
	SPA SNA
	TAD	P40
	CIA CLL
	DCA	TXTADR
	TAD	PSYMB+1
	DCA	NXTLCN
	TAD	PSYMB
	CLL RTL
	RAL
	TAD	CDF
	DCA	SCANTB
AT77,	ISZ	TXTADR
	JMP	SCANTB
	TAD	NXTLCN
	DCA%	PLETPS+1
	TAD	SCANTB
	CLL RTR
	RAR
	AND	PP7
	DCA%	PLCNM1+1
	JMP%	FINDIT

TESTAT,	ISZ	ATSW
	JMP	AT77
SCANTB,	NOP
	TAD%	NXTLCN
	CDF 10
	AND	P77
	TAD	M77
	SZA CLA
	CMA
	DCA	ATSW
	ISZ	NXTLCN
	JMP 	TESTAT
	TAD	P10
	TAD	SCANTB
	DCA	SCANTB
	JMP	TESTAT
P40,	40
P77,	77
M77,	-77
CDF,	6201
P10,	10

FINDRT,	0
	TAD	LETTER
	AND	P77
	JMS	FINDIT
	CIF CDF
	JMP%	FINDRT

PASNUM,	0
	TAD	TXTADR
	IAC
	SNA
	JMP	USZRO
	TAD	T2
	SPA
	JMP	USZRO
	TAD	M15
	SPA CLA
	JMP	USEIT
USZRO,	CLA
INDEX,	TAD	P60
	JMS	FINDIT
	CIF CDF
	JMP%	PASNUM
USEIT,	TAD	TXTADR
	JMP	INDEX

PASINT,	0
	TAD	TXTADR	/UPPER CASE: 1-63(10),1-77(8)
	SPA SNA	/LOWER CASE/GREEK:64-127(10),100-177(8)
	JMP	USSPAC	/CENTEREDS:200-217(10),310-331
	TAD	M332
	SMA
	JMP	USSPAC	/.GT. 217(10) BAD
	TAD	A22
	SMA
	JMP	OKVAL	/CENTEREDS
	TAD	P110
	SMA CLA
	JMP	USSPAC	/ILLEGAL: 128-199(10),200-307(8)
	TAD	TXTADR
ACHAR,	JMS	FINDIT
	CIF CDF
	JMP%	PASINT
USSPAC,	CLA
	TAD	P40
	JMP	ACHAR
OKVAL,	TAD	P200	/PASS CENTEREDS AS 200-221(8)
	JMP	ACHAR
P200,	200
A22,	22
P110,	110
M332,	-332
P60,	60
M15,	-15
T2,	2
	ORG	NXTLCN+200
	EXTERN	#HANG
NINPLT,	0
	TAD	TOTSTP
	CMA
	DCA	TOTSTP
	JMS%	PSPCAS+1
MORE,	ISZ	TOTSTP
	JMP	ANOTHR
DONE,	CIF CDF
	JMP%	NINPLT
ANOTHR,	JMS%	PFIGUR+1
	TAD	PDPXR
	JMS	PLDBL
	JMP	MORE
PLDBL,	0
	TAD	POCTBL+1
	DCA	PLTVCT
	CIF 10
	TAD	BUFCNT
	TAD	MBUFLG
	SPA CLA
	JMP	ISROOM
	IOF
	CIF 0
	JMS%	PHANG+1
DISPTR,	0
	ION
ISROOM,	TAD%	PLTVCT
	DCA%	PICHAR+1
	ISZ	PICHAR+1
	TAD	PICHAR+1
	CIA
	TAD	PBMX+1
	SMA CLA
	JMP 	LIMOK
	TAD	PBMN+1
	DCA	PICHAR+1
LIMOK,	ISZ	BUFCNT
	JMP%	PLDBL
	JMP	OUTSUB

PENOP,	0
	TAD	PDPXR
	JMS	PLDBL
	CIF CDF
	JMP%	PENOP
PDPXR,	0
TOTSTP,	0
XHOLD,
PSPCAS,	ADDR	SPCAS
YHOLD,
POCHAR,	ADDR	USBFMN
INTFLG,
PHANG,	ADDR	#HANG
PICHAR,	ADDR	USBFMN
BUFCNT,
POCTBL,	ADDR	OCT8BL
MBUFLG,
PBMN,	ADDR	USBFMN
PFIGUR,	ADDR	FIGURE
PLTVCT,
PBMX,	ADDR	USBFMX

OUTSUB,	CLA
	TAD%	POCHAR+1
	DCA	QTEMP5
	ISZ	POCHAR+1
	TAD	POCHAR+1
	CIA
	TAD	PBMX+1
	CLL
	SMA CLA
	JMP	CLRFLG
	TAD	PBMN+1
	DCA	POCHAR+1
CLRFLG,	TAD	QTEMP5
	SMA CLA
	JMP	TWOWD
QTEMP5,	0
	DCA	.-1
TWOWD,	TAD	QTEMP5
	AND	K3
	CLL RAR
	SZL
	CLA CMA
	TAD	XHOLD
	6060
	DCA	XHOLD
	TAD	QTEMP5
	7002		/BSW
	AND	K3
	CLL RAR
	SZL
	CLA CMA
	TAD	YHOLD
	6072
	DCA	YHOLD
	TAD	INTFLG
	SNA CLA
	JMP%	PLDBL
	DCA	INTFLG
	CIF CDF
	JMP%	XDISMS+1
XDISMS,	ADDR	#DISMS
K3,	3

INTPLT,	0
	CLA CMA
	TAD	BUFCNT
	SPA
	JMP	EMPTY
	DCA	BUFCNT
	ISZ	INTFLG
	NOP
	JMP	OUTSUB
EMPTY,	CLA CMA
	DCA	BUFCNT
	JMP%	INTPLT

DONECK,	0
	CLA
	JMS	PLDBL
WAIT,	TAD	BUFCNT
	SMA CLA
	JMP	WAIT
	6074		/BACK TO DISPLAY
	6077
	CIF CDF
	JMP%	DONECK
</pre>
<hr/>
</div>