File: PXOPEN.SB of Tape: Sources/Other/new-14

(Source file text) 

---

/	SUBROUTINE POPEN(IPIC)
	LAP 
\JPLOT, COMMN 3000
\JEXTR, COMMN 2600
\JCHRS, COMMN 1400
\ICOMM, COMMN 1
\FNAME, COMMN 3
\IGREC, COMMN 1
\IGCHR, COMMN 1
\IDUDS, COMMN 33
\IDASH, COMMN 1
\IDSHC, COMMN 1
\IDSHP, COMMN 1
\X0,	COMMN 3
\Y0,	COMMN 3
\FAKTX, COMMN 3
\FAKTY, COMMN 3
\IFONT, COMMN 1
\DXW,	COMMN 3
\DYW,	COMMN 3
\DXH,	COMMN 3
\DYH,	COMMN 3
/
	OPDEF TADI 1400
	OPDEF DCAI 3400
/
P7617,	7617
P7620,	7620
P7700,	7700
P200,	200
P10,	10
/
INHNDL,	74		/VOLATILE LOCATIONS !!!!!!
FICHCT,	117		/**
FINTMP,	120		/**
IHNDLR,	122		/**
FINREC,	616		/**
/
DUMMY	\IPIC
\IPIC,	BLOCK 2
/
	ENTRY POPEN
POPEN,	BLOCK 2
	TAD I POPEN
	DCA \IPIC
	INC POPEN#
	TAD I POPEN
	DCA \IPIC#
	INC POPEN#
	6212		/CIF 10
	JMS I P7700	/SET DF CURRENT, CALL USR
	10		/LOCK
	TAD (2000
	TAD \ICOMM
	SZA CLA 
	JMP OPNEW
	CLA CMA
	DCA I \IPIC	/WAS CHAIN BACK FROM PXPB
	JMP OPOLD
/ 
OPNEW,	TAD I \IPIC	/CHAIN FROM CCL ?
	SNA CLA
	JMP OPCHN	/YES
	6212		/CIF 10
	JMS I P200	/USR
	5		/DECODE
	2014		/.PL
	CLA		/DELETE TENT FILES
OPCHN,	DCA I \IPIC	/SIGNAL NEW FILE
	6211		/CDF 10
	TADI P7617	/GET HANDLER NUMBER
	AND (17
	DCA \FNAME	/TO COMMON
	TADI P7620
	DCA \FNAME#	/BLK NUMBER ALSO
OPOLD,	6201		/CDF 0
	TADI INHNDL	/GET HANDLER PAGE
	DCA FEARG	/SET FETCH ARGUMENT
	TAD \FNAME	/GET HANDLER NUMBER
	6212		/CIF 10
	JMS I P200
	1		/FETCH
FEARG,	0
	JMP FERR
	TAD \FNAME#	/GET BLOCK NUMBER
	6201		/CDF 0
	DCAI FINREC	/TO FINREC
	TAD FEARG
	DCAI IHNDLR	/SET ENTRY POINT
	CLA CMA
	DCAI FICHCT	/SET CHAR COUNT
	TAD P10
	DCAI FINTMP	/PRESET HIGH-ORDER BIT-BUFFER
	TAD (212
	TLS		/SET TTY FLAG AGAIN
	CLA
	RETRN POPEN

FERR,	CALL 1,ERROR
	ARG POP
POP,	TEXT "PXOP"
	END 

---