File: HEAD50.PA of Disk: V50/Source/Source-Listing-PAL-2
(Source file text)
/HEADER.PA V50.1
/
/
/
/
/
/
/
/
/
/COPYRIGHT (C) 2020 BY W. VAN DER MARK
/
/
/
MQL=7421
MQA=7501
SCA=7441
DPSZ=7451
DPIC=7573
DCM=7575
SAM=7457
KCF=6030
TFL=6040
TSF=6041
TCF=6042
TPC=6044
TSK=6045
TLS=6046
LBM=6170
RBM=6171
RLB=6172
RMR=6173
MBC=6174
RACA=6175
RACB=6176
RACC=6177
LXM=6200
GTS=6210
RTS=6220
RXM=6230
LRR=6240
RRR=6250
LUSR=6260
RUSR=6270
BATCCL=7777
KMON=7600
DVCTWT=7760
SYSDAT=7666
INBUF=6700
FIELD 0
*0012
XR2, 0000
GETLPT, 1004
ENFROM, 7773
ENTO, 1723
1020
0000
PRNTIT, 0000
WRFLG, 7777
DIRPNT, 0000
WRITOK, 0000
LBLCNT, 0000
LBLPNT, 0000
PRINT, XPRINT
CRLF, XCRLF
HELP, XHELP
YN, 0000
KMEXIT, 7605
USR, 7700
RDEVNA, BDEVNA
READ, XREAD
TYPE, XTYPE
CHAR1, 0000
CHAR2, 0000
0000
TMP, 0000
ENTRY, 7200
DELFLG, 0000
PNT1, 0000
CNT, 0000
COCNT, 0000
CHTMP, 0000
CHCNT, 0000
CHPNT, 0000
CHHALF, 0000
PAGE
PAGE2,
START, CLA CLL
TAD I (BATCCL
SPA CLA
JMP I KMEXIT
CIF 10
JMS I USR
0010
TAD (200
DCA USR
JMS I CRLF
JMS I PRINT
MHVERS
JMS I CRLF
STRTEN, JMS I PRINT
MWHELP
JMS SWIT
CLA CMA
DCA YN
JMP I (GDEVNA
XPIND, 0000
DCA CHAR1
TAD XPIND
DCA I (SWITCH
JMP I (SWITCH+1
XPRINT, 0000
CDF 0
KCC
TAD I XPRINT
DCA XPIND
ISZ XPRINT
XPRNX, TAD I XPIND
RTR
RTR
RTR
JMS XPRBYT
TAD I XPIND
JMS XPRBYT
ISZ XPIND
JMS I (CTRLO
JMP I XPRINT
JMP XPRNX
XPRBYT, 0000
AND (77
SNA
JMP I XPRINT
TAD (-40
SPA
TAD (100
TAD (240
JMS I TYPE
JMS I (CTRLC
JMP I XPRBYT
XHELP, 0000
CDF 0
TAD I XHELP
DCA XANPR
ISZ XHELP
TAD YN
SNA CLA
JMP I XHELP
JMS I PRINT
XANPR, 0000
JMS I CRLF
JMP I XHELP
SWIT, 0000
KSF
JMP .-1
KRB
JMS XPIND
-203
KMON
-3
KMON
-331 /Y
XYES
-131 /Y
XYES
-316 /N
XNO
-116 /N
XNO
0000
JMS I CRLF
JMS I PRINT
MPLYN
JMS I CRLF
JMP SWIT+1
XYES, JMS I PRINT
MYES
JMP XYES2
XNO, ISZ SWIT
JMS I PRINT
MNO
XYES2, JMS I CRLF
JMP I SWIT
PAGE
GDEVNA, JMS I HELP
MPARBL
JMS I HELP
MDEC8
JMS I CRLF
JMS I HELP
MINKM
TRYA, JMS I CRLF
JMS I PRINT
MDEVNA
JMS I (GETLIN
JMS I CRLF
JMS I RDEVNA
SKP
JMP .+4
JMS I PRINT
MBADIN
JMP GDEVNA
TAD CHAR1
DCA UDEVNA
TAD CHAR2
DCA UDEVNO
TAD (HNDBUF+1
DCA UDEVEN
CIF 10
JMS I USR
0001
UDEVNA, AND 0000 /NAME
UDEVNO, AND 0000 /DEVNO
UDEVEN, AND 0000 /ENTRY
JMP 0417
TAD UDEVEN
DCA ENTRY
TAD UDEVNO
TAD (DVCTWT-1
DCA UDEVNA
CDF 10
TAD I UDEVNA
CDF 0
DCA I (DVCTW
TAD I (DVCTW
SPA CLA
JMP .+4
JMS I PRINT
MDEVNF
JMP TRYA
JMS I (READIR
TAD (DIRHDR-1
DCA XR2
CDF 10
TAD (427
DCA I XR2
TAD (1203
DCA I XR2
CLA CMA
DCA I XR2
JMS I (UADVNM
JMS I (DESLBL
JMS I (SYSUPD
JMS I (DIRDAT
JMS I (GLNSTD
/JMS I (UADVNM
/JMS I (DESLBL
JMS I (WRALL
JMS I (WRHDR
JMP I (ENDPRC
CHNGIT, 0000
CDF 0
TAD PRNTIT
SNA CLA
JMP CHNG1
JMS I CRLF
JMS I PRINT
MCHNG
JMS I (SWIT
JMP .+3
CHNG1, ISZ CHNGIT
JMP I CHNGIT
DCA WRFLG
JMP I CHNGIT
CTRLC, 0000
KSF
JMP I CTRLC
KRS
TAD (-203
SZA CLA
JMP I CTRLC
TSF
JMP .-1
JMP I (KMON
CTRLO, 0000
KSF
JMP CTRL2
KRS
TAD (-217
SZA CLA
JMP CTRL2
KCC
JMP I CTRLO
CTRL2, ISZ CTRLO
JMP I CTRLO
PAGE
READIR, 0000
JMS I ENTRY
1410
DIRBUF
0001
JMP READER
CLA CMA
DCA WRITOK
CDF 10
TAD I (DIRBUF
CLL
TAD (100
SNL CLA
JMP BADDIR
DCA I (SAVNXT
TAD (DIRNXT
DCA DIRPNT
TAD I DIRPNT
SNA CLA
JMP .+5
TAD (400
TAD DIRPNT
DCA DIRPNT
JMP .-6
CDF 0
TAD DIRPNT
TAD (-DIRHDR
SPA CLA
JMP BADDIR+1
JMS I PRINT
MDIRPA
JMP I KMEXIT
BADDIR, DCA WRITOK
CDF 10
ISZ I (HDRFLG
JMP I READIR
JMS MULTPR
MDVHPA
MWISH
MWISHA
MWISHB
MWISHC
0000
JMS I (GETABC
JMP I READIR
CLA CMA
DCA PRNTIT
JMP I (GUDVNM
MULTPR, 0000
CDF 0
TAD I MULTPR
ISZ MULTPR
SNA
JMP I MULTPR
DCA .+2
JMS I PRINT
AND 0000
JMS I CRLF
JMP MULTPR+1
READER, JMS I CRLF
JMS I PRINT
MERB16
JMS I CRLF
JMS I PRINT
MCONTI
JMS I (SWIT
SKP
JMP I (STRTEN
DCA WRITOK
JMS I PRINT
MDIRZE
JMS I CRLF
JMP I READIR
CONDEC, 0000
DCA COCNT
CONLUP, DCA PNT1
TAD I GETLPT
SNA
JMP CONEXI
DCA CNT
TAD CNT
TAD (-260
CLL
TAD (-12
SNL CLA
JMP .+7
TAD COCNT
SZA CLA
JMP CONEXI
JMS I PRINT
MCONER
JMP I CONDEC
TAD PNT1
CLL RAL
DCA PNT1
TAD PNT1
CLL RAL
CLL RAL
TAD PNT1
DCA PNT1
TAD CNT
AND (17
TAD PNT1
ISZ COCNT
JMP CONLUP
CONEXI, TAD PNT1
ISZ CONDEC
JMP I CONDEC
PAGE
GLNSTD, AND 0000
JMS I (WRDATE
JMS I (GEDVLN
SNA CLA
JMP ASKDVL
JMS I HELP
MDEVSL
JMS I HELP
MAYNMQ
JMS I HELP
MNSDEV
JMS I HELP
MSTDVA
JMS I HELP
MVDEVS
JMS I CRLF
JMS I PRINT
MSTDVL
JMS I (SWIT
JMP STDLEN
ASKDVL, JMS I PRINT
MDVLDC
JMS I (GETLIN
JMS I (CONDEC
JMP .-4
CMA IAC
SKP
STDLEN, JMS I (GEDVLN
CDF 10
DCA I (HDRLEN
CDF 0
JMS I CRLF
BADSTR, JMS I HELP
MNXPRZ
JMS I HELP
MSTBEG
JMS I HELP
MSTD07
JMS I HELP
MSTD56
CDF 10
TAD I (HDRSYS
SZA CLA
TAD (61
TAD (7
DCA I (HDRSTR
JMS I PRINT
MSTDST /USE STD START
JMS I (SWIT
JMP I GLNSTD
JMS I PRINT
MFSTBL
JMS I (GETLIN
JMS I (CONDEC
JMP .-4
CDF 10
DCA I (HDRSTR
TAD I (HDRSTR
CDF 0
TAD (-7
SPA CLA
JMP BADSTR
JMP I GLNSTD
DIRDAT, AND 0000
JMS I (WRDATE
JMS I CRLF
JMS I HELP
MDIDAH
JMS I PRINT
MDIASK
JMP DIRASK
CLA
JMS I PRINT
MDIERR
DIRASK, JMS I (GETLIN
JMS I (CONDEC
JMP DIRASK-3
CDF 10
TAD (-3662 /-1970
DCA I (HDRDID
TAD I (HDRDID
SPA
JMP DIRASK-3
TAD (-100 /-2034+1970
SMA CLA
JMP DIRASK-3
CDF 0
JMP I DIRDAT
PAGE
GUDVNM, CLA CMA
DCA WRFLG
JMS I CRLF
JMS I PRINT
MUDVNM
TAD (HDRUSA
JMS I (PRNTNZ
-4
JMS I PRINT
MVOLID
CDF 10
TAD I (HDRVOL
JMS I (DECCON
JMS I (CHNGIT
JMS I (UADVNM
JMS I CRLF
JMS I PRINT
MDESLB
JMS I CRLF
TAD (HDRLBL
JMS I (PRNTNZ
-200
JMS I (CHNGIT
JMS I (DESLBL
JMS I CRLF
CDF 10
TAD I (HDRSYS
SNA CLA
JMP NOSID
TAD I (HDRSID
CDF 0
TAD (MSIDSW
DCA PNT1
TAD I PNT1
DCA .+4
JMS I PRINT
MSYSID
JMS I PRINT
0000
JMS I PRINT
MVERS
CDF 10
TAD I (HDRVER
JMS I (DECCON
CDF 10
TAD I (HDRREL
TAD (300
JMS I TYPE
JMP NOSID+2
NOSID, JMS I PRINT
MNOSYS
JMS I (CHNGIT
JMS I (SYSUPD
JMS I CRLF
JMS I PRINT
MINDAT
CDF 10
TAD I (HDRDAT
RTR
RAR
AND (37
JMS I (DECCON
TAD ("-
JMS I TYPE
CDF 10
TAD I (HDRDAT
BSW
RTR
AND (17
JMS I (DECCON
TAD ("-
JMS I TYPE
CDF 10
TAD I (HDRDAT
AND (7
DCA XTEMP
TAD I (HDRBAT
RTR
RTR
AND (70
TAD XTEMP
TAD (3662 /1970
JMS I (DECCON
CDF 10
TAD I (HDRDID
SNA CLA
JMP GUDVN2
JMS I CRLF
JMS I PRINT
MDIDAP
CDF 10
TAD I (HDRDID
TAD (3662 /1970
JMS I (DECCON
GUDVN2, JMS I (CHNGIT
JMS I (DIRDAT
JMS I CRLF
JMP I (DVLDC
XTEMP, 0
PAGE
DVLDC, JMS I PRINT
MDVLDC
CLA CMA
CDF 10
DCA I (HDRFLG
TAD I (HDRLEN
CMA IAC
JMS DECCON
JMS I CRLF
JMS I PRINT
MFSTBL
CDF 10
TAD I (HDRSTR
JMS DECCON
JMS I (CHNGIT
JMS I (GLNSTD
JMS I CRLF
ISZ WRFLG
JMS I (WRHDR
JMS I CRLF
JMP I (ENDPRC
DECCON, 0000
CDF 0
DCA DECINP
CLA CLL CML RAR
DCA DECDIG
DCA DECINC
TAD DECTBL-1
DCA DECCNT
TAD DECTBL-2
DCA DECLUP
SKP
DECLU0, DCA DECINP
CLL
TAD DECINP
DECLUP, TAD DECTBL
SZL
ISZ DECINC
SZL
JMP DECLU0
CLA
TAD DECINC
SNA CLA
JMP .+3
TAD DEC0
DCA DECDIG
TAD DECINC
TAD DECDIG
SMA
JMS I TYPE
CLA
DCA DECINC
ISZ DECLUP
ISZ DECCNT
JMP DECLUP-1
TAD DECDIG
SMA CLA
JMP I DECCON
TAD DEC0
JMS I TYPE
JMP I DECCON
TAD DECTBL
-4
DECTBL, -1750 /-1000
-144 /-100
-12 /-10
-1 /-1
DEC0, 260
DECINP, AND 0000
DECINC, AND 0000
DECCNT, AND 0000
DECDIG, JMS 0000
REC3, JMS I HELP
MMMMMT
JMS I HELP
MSCRLL
CLA CLL CMA RAL
DCA DECINP
TAD (-5
DCA DECINC
RECC, JMS I ENTRY
0210
SAVHDR
0050
CLA CLL
ISZ DECINC
JMP RECC
JMS I HELP
MMMMMM
ISZ DECINP
JMP RECC-2
REC4, JMS I HELP
MTHNKS
JMS I CRLF
TAD (RECOVR-2
DCA I (DVCTEN
JMS I CRLF
JMP I (STRTEN
XX, AND 0000
DCA CHTMP
TAD CHTMP
RTR
RTR
RTR
JMS I TYPE
TAD CHTMP
JMS I TYPE
JMP I XX
PAGE
SYSUPD, 0000
CLA CLL
CDF 10
DCA I (HDRSYS
CDF 0
TAD (HDRBLK
JMS I (ZLOCS
-73
JMS I (WRDATE
JMS I PRINT
MISSYS
JMS I (SWIT
SKP
JMP I SYSUPD
CLA CMA
CDF 10
DCA I (HDRSYS
CDF 0
SYSU2, JMS I PRINT
MSYSID
JMS I CRLF
JMS I HELP
M0EQUN
JMS I HELP
M1PS8
JMS I HELP
M2OS8
JMS I HELP
M3OS12
JMS I HELP
M4DECS
JMS I HELP
M5OS78
JMS I HELP
M6ETOS
JMS I HELP
M7MLTI
JMS I HELP
M8MLTO
JMS I (GETLIN
JMS I (CONDEC
JMP SYSU2
CMA IAC
CDF 10
DCA I (HDRSID
CDF 0
JMS I PRINT
MVERSY
JMS I (GETLIN
JMS I (CONDEC
JMP .-4
CDF 10
DCA I (HDRVER
CDF 0
JMS I PRINT
MVERCO
JMS I (GETLIN
JMS I (CONDEC
JMP .-4
CDF 10
DCA I (HDRREL
DCA I (HDR10
DCA I (HDR11
CDF 0
JMP I SYSUPD
GETABC, 0000
KSF
JMP .-1
KRB
TSF
JMP .-1
TLS
JMS I (XPIND
-301
GETA
-101
GETA
-302
GETB
-102
GETB
-303
GETC
-103
GETC
0000
JMS I CRLF
JMS I PRINT
MANABC
JMP GETABC+1
GETC, ISZ GETABC
GETB, ISZ GETABC
GETA, JMS I CRLF
JMP I GETABC
GEDVLN, 0000
TAD DVCTW
AND (770
CLL RTR
RAR
TAD (DVLENT
DCA PNT1
TAD I PNT1
JMP I GEDVLN
DVCTW, AND 0000
DVCTEN, RECOVR-2
JMP I DVCTEN
DVCTER, CLA CLL
ISZ DVCTEN
ISZ DVCTEN
JMP I DVCTEN
PAGE
ZLOCS, 0000
DCA XR2
TAD I ZLOCS
DCA ZLOCSP
ISZ ZLOCS
CDF 10
DCA I XR2
ISZ ZLOCSP
JMP .-2
CDF 0
JMP I ZLOCS
ZLOCSP, 0000
UADVNM, 0000
JMS I (WRDATE
TAD (HDRZ6
JMS ZLOCS
-6
JMS I CRLF
JMS I HELP
MUSALO
JMS I HELP
MAUTOA
JMS I HELP
M2CHAR
JMS I HELP
MUNIQE
USAAGN, JMS I PRINT
MUDVNM
JMS I (GETLIN
TAD (HDRUSA
DCA PNT1
TAD (-4
DCA CNT
USALUP, TAD I GETLPT
SNA
JMP .+7
CDF 10
DCA I PNT1
CDF 0
ISZ PNT1
ISZ CNT
JMP USALUP
TAD (INBUF-1
DCA GETLPT
JMS I RDEVNA
JMP UADVNM+1
TAD CHAR2
SNA CLA
CLA CMA
DCA TMP
TAD CHAR1
TAD CHAR2
CLL RAL
ISZ TMP
CLL CML
RAR
CDF 10
DCA I (HDRUDV
TAD I (HDRUDV
CDF 0
JMS I (CHKUSA
MVOLE2, JMS I HELP
MVOLEL
JMS I HELP
MDECLT
JMS I PRINT
MVOLID
JMS I (GETLIN
JMS I (CONDEC
JMP MVOLE2
CDF 10
DCA I (HDRVOL
CDF 0
JMP I UADVNM
RECOVR, TAD YN
SNA CLA
JMP REC1
JMS I HELP
MWRENA
JMS I (SYNC
JMS I (DVCTEN
JMS I (WRHDR
JMP I (STRTEN
REC1, CLA CMA
DCA YN
JMS I HELP
MOUCH
JMS I HELP
MYFORG
JMS I (SYNC
JMS I (DVCTEN
JMS I (WRHDR
JMP I (REC4
JMS I HELP
MOUCH
JMS I HELP
MPRSW
REC2, JMS I (SYNC
JMS I (DVCTEN
JMS I (WRHDR
JMP I (REC3
JMS I (MULTPR
MOUCH
MDUMMY
MWRNEN
MGHELP
0000
JMP REC2
PAGE
DESLBL, 0000
JMS I (WRDATE
TAD (HDRLBL-1
JMS I (ZLOCS
-200
JMS I HELP
MDESAS
JMS I HELP
M127CH
JMS I HELP
MTERMZ
JMS I HELP
MTERCR
JMS I PRINT
MDESLB
TAD (-200
DCA LBLCNT
TAD (HDRLBL
DCA LBLPNT
JMP LBLSTR
TAD (215
JMS LBLGET
TAD (212
JMS LBLGET
LBLSTR, JMS GETLIN
TAD I GETLPT
SNA
JMP LBLSTR-4
JMS LBLGET
JMP LBLSTR+1
LBLGET, 0000
CDF 10
DCA I LBLPNT
TAD I LBLPNT
CDF 0
TAD (-232
SNA CLA
JMP LBLOUT
ISZ LBLPNT
ISZ LBLCNT
JMP I LBLGET
JMS I PRINT
MTH128
LBLOUT, CDF 10
DCA I LBLPNT
CDF 0
JMP I DESLBL
WRALL, 0000
ISZ WRITOK
SKP
JMP I WRALL
TAD (DIRBUF
JMS I (ZLOCS
-6
CDF 10
TAD I (HDRSTR
DCA I (DIRSTR
CLA CMA
DCA I (DIRBUF
CLA CMA
DCA I (DIRADD
TAD I (HDRLEN
TAD I (DIRSTR
DCA I (DIRFIL
CDF 0
JMS I ENTRY
5210
DIRBUF
AND 0001
HLT
JMP I WRALL
WRHDR, 0000
JMS I ENTRY
4210
DIRHDR
0006
JMP I (DVCTER
JMP I WRHDR
GETLIN, 0000
CDF 0
JMS I READ
TAD (INBUF-1
DCA GETLPT
JMP I GETLIN
PRNTNZ, 0000
CDF 0
DCA PNT1
TAD I PRNTNZ
DCA COCNT
ISZ PRNTNZ
PRNTNL, CDF 10
TAD I PNT1
CDF 0
SZA
JMS I TYPE
ISZ PNT1
ISZ COCNT
JMP PRNTNL
JMP I PRNTNZ
XCRLF, 0000
TAD (215
JMS I TYPE
TAD (212
JMS I TYPE
JMP I XCRLF
PAGE
CHKUSA, 0000
CMA IAC
DCA TMP
TAD (DVLNAM-1
DCA XR2
TAD I XR2
SNA
JMP I CHKUSA
TAD TMP
SZA CLA
JMP .-5
JMS I PRINT
CHAR1
JMS I PRINT
MCONFL
TAD XR2
TAD (HDRUSA
DCA TMP
TAD TMP
CLL RAL
TAD TMP
TAD (MDVLST
DCA .+2
JMS I PRINT
MDVLST
JMS I CRLF
JMS I PRINT
MTRYAG
JMS I (SWIT
JMP I (USAAGN
JMP I CHKUSA
SYNC, 0000
KSF
JMP .-1
KCC
JMP I SYNC
BDEVNA, 0000
DCA CHAR1
DCA CHAR2
DCA TMP
TAD (CHAR1
DCA CHPNT
CLA CMA
DCA CHHALF
BDEV4, DCA CHCNT
TAD I GETLPT
TAD (-240
SNA
JMP .-3
TAD (240
SKP
BDEVOF, TAD I GETLPT
DCA CHTMP
TAD CHTMP
TAD (-256
SNA
JMP BDEVNX
TAD (-2
CLL
TAD (-12
SNL CLA
JMP BDEVOK
TAD (-301
TAD CHTMP
CLL CML
TAD (-32
SNL CLA
JMP BDEVEN
BDEVOK, TAD CHCNT
TAD (-6
SMA CLA
JMP BDEVOF
TAD CHCNT
CLL RAR
TAD CHPNT
DCA PNT1
TAD CHTMP
AND (77
SZL
JMP .+4
RTL
RTL
RTL
TAD I PNT1
DCA I PNT1
ISZ CHCNT
JMP BDEVOF
BDEVNX, ISZ CHHALF
JMP BDEVEN
ISZ CHPNT
TAD (4
JMP BDEV4
BDEVEN, TAD CHCNT
SZA CLA
ISZ BDEVNA
JMP I BDEVNA
XTYPE, 0000
JMP .+3
TSF
JMP .-1
TLS
CLA
TAD (NOP
DCA XTYPE+1
JMP I XTYPE
PAGE
XREAD, AND 0000
/TAD (":
/JMS I TYPE
DCA DELFLG
TAD (INBUF-1
DCA GETLPT
PRIGN, KSF
JMP .-1
TAD (200
KRS
DCA CHAR1
KCC
JMS SWITCH
-225 /^U
PRCTL
-215 /CR
PRCR
-377 /DEL
PRDEL
-375 /}
PRESC
-376 /~
PRESC
-233 /ESC
PRESC
-212 /LF
PRLF
-200 /NULL
PRIGN
-217 /^O
PRIGN
-203 /^C
KMON+5
0000
JMS PRSUB
TAD CHAR1
DCA I GETLPT
TAD GETLPT
TAD (-INBUF-110
SPA CLA
JMP PRIGN
PRCR, JMS I CRLF
TAD GETLPT
TAD (-INBUF+1
SNA CLA
JMP XREAD+1
DCA I GETLPT
DCA I GETLPT
JMP I XREAD
PRSUB, 0000
ISZ DELFLG
JMP .+3
TAD (334 /\
JMS I TYPE
DCA DELFLG
TAD CHAR1
JMS I TYPE
JMP I PRSUB
PRCTL, TAD (336 /^
JMS I TYPE
TAD CHAR1
TAD (100
JMS I TYPE
PRCTL2, JMS I CRLF
ISZ SWITCH
TAD I SWITCH
SZA CLA
JMP XREAD+3
JMP XREAD+1
PRESC, TAD (244 /$
DCA CHAR1
JMS PRSUB
JMP PRCR+1
PRDEL, TAD GETLPT
TAD (-INBUF+1
SNA CLA
JMP PREMP
TAD (334
ISZ DELFLG
JMS I TYPE
CLA CMA
DCA DELFLG
TAD GETLPT
DCA PNT1
TAD I PNT1
JMS I TYPE
PRLF2, CLA CMA
TAD GETLPT
JMP PRIGN-1
PREMP, ISZ DELFLG
JMP PRCTL2
TAD (334
JMP PRCTL2-1
SWITCH, 0000
TAD I SWITCH
ISZ SWITCH
SNA
JMP I SWITCH
TAD CHAR1
SNA CLA
JMP .+3
ISZ SWITCH
JMP SWITCH+1
TAD I SWITCH
DCA PNT1
JMP I PNT1
PRLF, JMS I CRLF
DCA I GETLPT
TAD (INBUF-1
DCA 0017
TAD I 0017
SNA
JMP PRLF2
JMS I TYPE
JMP .-4
PAGE
WRDATE, 0000
TAD I (BATCCL
AND (1600
CDF 10
DCA I (HDRBAT
TAD I (SYSDAT
DCA I (HDRDAT
CDF 0
JMP I WRDATE
ENDPRC, JMS I PRINT
MSQVOL
JMS I (SWIT
SKP
JMP I (STRTEN
JMS I CRLF
JMS I PRINT
MMNTNV
JMS I (SWIT
NOP
CDF 10
ISZ I (HDRVOL
CLA CLL
TAD (DIRHDR-1
DCA ENFROM
TAD (SAVHDR+400-1
DCA ENTO
TAD I ENFROM
DCA I ENTO
TAD ENTO
TAD (-SAVHDR-1000
SPA CLA
JMP .-5
CDF 0
JMS I ENTRY
1410
2000
0001
JMP .-4
CLA CMA
DCA WRITOK
CDF 10
TAD I (DIRBUF
CLL
TAD (100
SNL CLA
JMP BADHDR
DCA I (SAVNXT
TAD (DIRNXT
DCA DIRPNT
TAD I DIRPNT
SNA CLA
JMP .+5
TAD (400
TAD DIRPNT
DCA DIRPNT
JMP .-6
CDF 0
TAD DIRPNT
TAD (-DIRHDR
SPA CLA
JMP BADHDR+1
JMS I PRINT
MDIRPA
JMP I KMEXIT
BADHDR, DCA WRITOK
CDF 10
CLA CLL
DCA PRNTIT
TAD (DIRHDR-1
DCA ENTO
TAD (5400-1
DCA ENFROM
TAD I ENFROM
DCA I ENTO
TAD ENTO
TAD (-6000
SPA CLA
JMP .-5
CDF 0
CLA CLL
DCA PRNTIT
JMP I (GUDVNM+1
PAGE
DVLENT, 0000/03200-0000 @@ /0: TTY
0000/03201-0000 @@ /1: PTR
0000/03202-0000 @@ /2: PTP
7134/03203-7134 9\ /3: CDR
0000/03204-0000 @@ /4: LPT
1520/03205-1520 MP /5: RK08 (1520= - DECIMAL 3248)
6001/03206-6001 0A /6: RF08 IN VARIOUS SIZES
4001/03207-4001 A /7: "
2001/03210-2001 PA /10: "
0001/03211-0001 @A /11: "(CHEATS A BLOCK ON LARGEST TO KEEP IT NON-ZERO)
7601/03212-7601 >A /12: DF32 IN VARIOUS SIZES
7401/03213-7401 <A /13: "
7201/03214-7201 :A /14: "
7001/03215-7001 8A /15: "(CHEATS A BLOCK TO AVOID HARDWARE TROUBLE)
6437/03216-6437 4_ /16: TC08 DECTAPE
6437/03217-6437 4_ /17: LINCTAPE
0000/03220-0000 @@ /20: MAGTAPE
6437/03221-6437 4_ /21: TD8E
0000/03222-0000 @@ /22: BAT: BATCH HANDLER
1520/03223-1520 MP /23: 1/2 OF AN RK8E
0000/03224-0000 @@ /24: NULL: NULL HANDLER
7022/03225-7022 8R /25: RX01 FLOPPY DISK
0017/03226-0000 @@ /26: RL01 A,B BIG
0000/03227-0000 @@ /27: TA8E CASSETTE
0000/03230-0000 @@ /30: PDP-12 SCOPE AND TEK DISPLAY
4027/03231-0000 @@ /31: RL01 C SMALL
0000/03232-0000 @@ /32: NEW RX MUST BE ZERO TO EXAMINE MEDIA
7600/03233-0000 @@ /33: VX EXT.MEM. PLATTER #1
7400/03234-0000 @@ /34: VX EXT.MEM. PLATTER #1,2
7200/03235-0000 @@ /35: VX EXT.MEM. PLATTER #1,2,3
0000/03236-0000 @@ /36: DUMP
7000/03237-0000 @@ /37: TU58 DECTAPE II (6-BIT BYTES)
1520/03240-0000 @@ /40: SYS. IND. MOD43 DISK
6556/03241-0000 @@ /41: RB01 1.5 DENSITY FLOPPY - INTERLEAVE 2
6556/03242-0000 @@ /42: RB07 1.5 DENSITY FLOPPY - INTERLEAVE 4
0000/03243-0000 @@ /43: EDOU
0000/03244-0000 @@ /44: EDIN
0000/03245-0000 @@ /USER DEVICES
0000/03246-0000 @@ /50: MULTI8 VIRTUAL DEV
0000/03247-0000 @@ /51: "
0000/03250-0000 @@ /52: "
0000/03251-0000 @@ /53: "
0000/03252-1520 MP /54: "
0000/03253-0000 @@ /55: "
0000/03254-0000 @@ /56: "
0000/03255-0000 @@ /57: "
0000/03256-0000 @@ /60: ASYNCHRONOUS COMMUNICATION
0000/03257-0000 @@ /XX:
0000/03260-0000 @@ /ZBBLOCK
0000/03261-0000 @@
0000/03262-0000 @@
0000/03263-0000 @@
0000/03264-0000 @@
0000/03265-0000 @@
0000/03266-0000 @@
0000/03267-0000 @@
0000/03270-0000 @@
0000/03271-0000 @@
0000/03272-0000 @@
0000/03273-0000 @@
0000/03274-0000 @@
0000/03275-0000 @@
0000/03276-0000 @@
0000/03277-0000 @@
DVLNAM, 4631 /SYS
5723 /DSK
5524 /TTY
4020 /LPT
4024 /PTP
4224 /PTR
6504 /CDR
4604 /DTA0
4605 /DTA1
4606 /DTA2
4607 /DTA3
4610 /DTA4
4611 /DTA5
4612 /DTA6
4613 /DTA7
4215 /RL0A
4216 /RL0B
4315 /RL1A
4316 /RL1B
4217 /RL0C
4317 /RL1C
4417 /RL2C
4517 /RL3C
6373 /RKA0
6374 /RKA1
6375 /RKA2
6376 /RKA3
6473 /RKB0
6474 /RKB1
6475 /RKB2
6476 /RKB3
6410 /RXA0
6411 /RXA1
6510 /RXB0
6511 /RXB1
0406 /DF
2206 /RF
2426 /TV
7241 /NULL
4503 /CSA0
4504 /CSA1
0303 /CC
5704 /MTA0
5705 /MTA1
6362 /RBA0
6363 /RBA1
6431 /EDOU
5622 /EDIN
0000 /@@
MDVLST, TEXT "SYS"
0000
TEXT "DSK"
0000
TEXT "TTY"
0000
TEXT "LPT"
0000
TEXT "PTP"
0000
TEXT "PTR"
0000
TEXT "CDR"
0000
TEXT "DTA0"
TEXT "DTA1"
TEXT "DTA2"
TEXT "DTA3"
TEXT "DTA4"
TEXT "DTA5"
TEXT "DTA6"
TEXT "DTA7"
TEXT "RL0A"
TEXT "RL0B"
TEXT "RL1A"
TEXT "RL1B"
TEXT "RL0C"
TEXT "RL1C"
TEXT "RL2C"
TEXT "RL3C"
TEXT "RKA0"
TEXT "RKA1"
TEXT "RKA2"
TEXT "RKA3"
TEXT "RKB0"
TEXT "RKB1"
TEXT "RKB2"
TEXT "RKB3"
TEXT "RXA0"
TEXT "RXA1"
TEXT "RXB0"
TEXT "RXB1"
TEXT "DF"
0000
TEXT "RF"
0000
TEXT "TV"
0000
TEXT "NULL"
TEXT "CSA0"
TEXT "CSA1"
TEXT "CC"
0000
TEXT "MTA0"
TEXT "MTA1"
TEXT "RBA0"
TEXT "RBA1"
TEXT "EDOU"
TEXT "EDIN"
M8MLTO
M7MLTI
M6ETOS
M5OS78
M4DECS
M3OS12
M2OS8
M1PS8
MSIDSW, M0EQUN
MCONER, TEXT "NOT NUMERIC INPUT"
MPLYN, TEXT "PLEASE ANSWER YES OR NO"
MWHELP, TEXT "DO YOU WANT HELP? "
MYES, TEXT "YES"
MNO, TEXT "NO"
MPARBL, TEXT "THIS PROGRAM ESTABISHES A PARAMETER BLOCK"
MDEC8, TEXT "ON OS-8 FILE STRUCTURED DEVICES"
MINKM, TEXT "INPUT IS VIA THE REGULAR MONITOR INPUT"
MDEVNA, TEXT "DEVICE NAME: "
MBADIN, TEXT "?BAD INPUT"
MDEVNF, TEXT "DEVICE NOT FILE STRUCTURED"
MDIRPA, TEXT "DIRECTORY OCCUPIES PARAMETER BLOCK"
MDVHPA, TEXT "DEVICE HAS PARAMETER BLOCK"
MDMPIT, TEXT "DO YOU WISH TO DUMP IT? "
MERB16, TEXT "HANDLER ERROR READING BLOCKS 1-6 (PARITY?)"
MCONTI, TEXT "SHALL I CONTINUE? "
MDIRZE, TEXT "DIRECTORY WILL BE ZEROED"
MSTDVL, TEXT "STANDARD DEVICE LENGTH? "
MDEVSL, TEXT "MOST DEVICES HAVE A STANDARD LENGTH"
MAYNMQ, TEXT "ANSWER YES TO THE NEXT QUESTION"
MNSDEV, TEXT "UNLESS YOU HAVE A NON-STANDARD DEVICE."
MSTDVA, TEXT "STANDARD DEVICES ARE:"
MVDEVS, TEXT " DTAN,LTAN,DF32,RF08,RK8,RXN,TD8E"
MDVLDC, TEXT "DEVICE LENGTH (DECIMAL): "
MINDAT, TEXT "INITIALIZED ON: "
MISSYS, TEXT "IS A SYSTEM PRESENT? "
MSYSID, TEXT "SYSTEM ID: "
M0EQUN, TEXT " 0=UNASSIGNED "
M1PS8, TEXT " 1=PS/8 "
M2OS8, TEXT " 2=OS/8 "
M3OS12, TEXT " 3=OS/12 "
M4DECS, TEXT " 4=DECSYSTEM-8/78 "
M5OS78, TEXT " 5=OS/78 "
M6ETOS, TEXT " 6=ETOS/8 "
M7MLTI, TEXT " 7=MULTI/8 "
M8MLTO, TEXT " 8=MULTOS/8 "
MVERSY, TEXT "VERSION NUMBER (ASSOCIATED WITH SYSTEM ARE; IE. 1,2,3 ETC.): "
MVERCO, TEXT "VERSION RELEASE CODE (IE. 1=A,2=B,3=C ETC.): "
MUDVNM, TEXT "USER ASSIGNED DEVICE NAME: "
MUSALO, TEXT "THE USER ASSIGNED NAME IS A LOGICAL NAME USED"
MAUTOA, TEXT "BY AUTOAS. IT IS RECOMMENDED THAT THIS NAME"
M2CHAR, TEXT "BE A TWO CHARACTER NAME STARTING WITH AN ALPHA"
MUNIQE, TEXT "TO INSURE UNIQUENESS."
MVOLID, TEXT " VOLUME ID: "
MVOLEL, TEXT "THE VOLUME ID IS AN EXTRA LABEL FOR IDENTIFICATION"
MDECLT, TEXT "PURPOSES ONLY. A DECIMAL NUMBER < 4096"
MDESLB, TEXT "DESCRIPTIVE LABEL: "
MDESAS, TEXT "THE DESCRIPTIVE LABEL MAY BE ANY STRING OF"
M127CH, TEXT "UP TO 127 CHARACTERS ON MULTIPLE LINES"
MTERMZ, TEXT "IT MUST BE TERMINATED WITH A ^Z (CNT/Z)"
MTERCR, TEXT "FOLLOWED BY A CARRIAGE RETURN."
MTH128, TEXT "MORE THAN 128 CHARS INPUT - TERMINATION FORCED"
MVERS, TEXT "VERSION: "
MSTDST, TEXT "USE STANDARD START OF FILE STORAGE? "
MFSTBL, TEXT "FILE STORAGE STARTS AT BLOCK (DECIMAL): "
MNOSYS, TEXT "NO SYSTEM PRESENT"
MNXPRZ, TEXT /THE NEXT PARAMETER IS USED FOR "ZERO" TO DETERMINE/
MSTBEG, TEXT "WHERE FILE STORAGE BEGINS"
MSTD07, TEXT "STANDARD IS 7 FOR NON-SYSTEM DEVICES,"
MSTD56, TEXT "65 FOR SYSTEM DEVICE"
MMMMMT, TEXT "MMMM!! THAT FEELS BETTER!"
MSCRLL, TEXT "SCRATCH A LITTLE TO THE LEFT...."
MMMMMM, TEXT "MMMMMMM!!"
MCHNG, TEXT "**CHANGE THIS**? "
MANABC, TEXT "PLEASE ANSWER A, B, OR C "
MWISH, TEXT "DO YOU WISH TO"
MWISHA, TEXT " A:REPLACE"
MWISHB, TEXT " B:SELECIVELY DECIDE"
MWISHC, TEXT " C:PRINT IT?"
MSQVOL, TEXT "SEQUENTIAL VOLUMES (Y OR N)? "
MMNTNV, TEXT "MOUNT NEW VOLUME, THEN TYPE Y: "
MWRENA, TEXT "PLEASE WRITE ENABLE THE DEVICE"
MOUCH, TEXT "OUCH!!"
MYFORG, TEXT "YOU FORGOT SOMETHING."
MTHNKS, TEXT "THANKS!"
MPRSW, TEXT "CLUE: YOU NEED TO PRESS A SWITCH"
MDUMMY, TEXT "YOU DUMMY! I CAN'T DO EVERYTHING"
MWRNEN, TEXT "THE DEVICE NEEDS TO BE WRITE ENABLED"
MGHELP, TEXT "NEXT TIME GET HELP!"
MTRYAG, TEXT "TRY ADAIN?"
MCONFL, TEXT " CONFLICTS WITH "
MHVERS, TEXT "HEADER VERSION 50"
MDIDAH, TEXT "DIRECTORY DATE SHOWS EPOCH OF FILES ON MEDIUM"
MDIASK, TEXT "PLEASE ENTER DIRECTORY DATE: "
MDIERR, TEXT "PLEASE ENTER YEAR BETWEEN 1971 AND 2034"
MDIDAP, TEXT "DIRECTORY DATE: "
0000
PAGE
*200 /STARTING ADDRESS
NOPUNCH
*7200
HNDBUF, /ZBLOCK 400
FIELD 1
*2000
DIRBUF, 0 /ZBLOCK 2400
DIRSTR, 0
DIRNXT, 0
0
DIRADD, 0
0
DIRFIL, 0
*4400
DIRHDR, 0427
1203
HDRFLG, 0
HDRLEN, 0
HDRZEA, 0
HDRSQO, 0
HDRSQM, 0
HDRSYS, 0
HDRSTR, 7
HDRDID, 0
*4476
HDRZ6, 0 /ZBLOCK 6
HDRUDV, 0
HDRUSA, ZBLOCK 4
HDRBLK, /ZBLOCK 73
HDRVOL, 0
HDRSID, 0
HDRVER, 0
HDRREL, 0
HDR10, 0
HDR11, 0
HDRDAT, 1234
HDRBAT, 0600
*4600
HDRLBL, 0
*DIRHDR+400
SAVHDR, 0
SAVSTR, 0
SAVNXT, 0
ENPUNCH
$$$$$$$$$$$$$$$$